// flagnpc.txt
// A very simple, naive text. Creature attacks anything it hates nearby.
// Once it has won, it returns to its home.
// Memory Cells:
//   Cell 0 - How creature moves.
//     0 - If 0, wander randomly. 
//     1 - Stands still until a target appears.
//     2 - Completely immobile, even if target appears.
//   Cell 1,2 - Unused.
//   Cell 3 - Dialogue node to start with if talked to. if left at 0, this
//     character doesn't talk.
//   Cell 4,5 - Stuff done flag. If both 0, nothing. Otherwise, when this
//     is talked to, the dialogue starts at node referenced by cell 7, if
//     the flag is equal to value of Cell 6.
//   Cell 6 - The SDF value for a new conversation node.
//   Cell 7 - Dialogue node to start with if talked to when SDF from 4,5
//     is equal to 1. If zero, the character doesn't talk when that SDF is
//     equal to 1.

begincreaturescript;

variables;

short i,target;

body;

beginstate INIT_STATE;
	if (get_memory_cell(0) == 2)
		set_mobility(ME,0);
	break;

beginstate DEAD_STATE; //erase him so that people can't screw up the plot

	message_dialog("Battered and bloody, Joshua looks as if he's about to collapse. But instead, he jumps into the river, vanishing without a trace.","");
	set_flag(1,14,1);
	erase_char(ME);	

break;

beginstate START_STATE; 
	// if I have a target for some reason, go attack it
	if (target_ok()) {
		if (dist_to_char(get_target()) <= 16)
			set_state(3);
			else set_target(ME,-1);
		}
	
	// Look for a target, attack it if visible
	if (select_target(ME,8,0)) {
		do_attack();
		set_state(3);
		}
		
	// Have I been hit? Strike back!
	if (who_hit_me() >= 0) {
		set_target(ME,who_hit_me());
		do_attack();
		set_state(3);
		}
		
	// Otherwise, just peacefully move around. Go back to start, if I'm too far
	// from where I started.
	if ((my_dist_from_start() >= 6) || ((my_dist_from_start() > 0) && (get_memory_cell(0) > 0))) {
		if (get_ran(1,1,100) < 40) 
			return_to_start(ME,1);
		}
		else if (get_memory_cell(0) == 0) {
			fidget(ME,25);
			}

	// if we're in combat and the above didn't give me anything to do, just
	// stop now. Otherwise, game will keep running script, and that eats up CPU time.
	if (am_i_doing_action() == FALSE)
		end_combat_turn();
break;

beginstate 3; // attacking
	if (target_ok() == FALSE)
		set_state(START_STATE);
	do_attack();
break;

beginstate TALKING_STATE;
	if ((get_memory_cell(4) != 0) || (get_memory_cell(5) != 0)) {
		if(get_flag(get_memory_cell(4),get_memory_cell(5)) == get_memory_cell(6)) {
			if(get_memory_cell(7) == 0) {
				print_str("Talking: It doesn't respond.");
				end();
				}
			begin_talk_mode(get_memory_cell(7));
			}
		else {
			if (get_memory_cell(3) == 0) {
				print_str("Talking: It doesn't respond.");
				end();
				}
			begin_talk_mode(get_memory_cell(3));
			}
		}
	else {
		if (get_memory_cell(3) == 0) {
			print_str("Talking: It doesn't respond.");
			end();
			}
		begin_talk_mode(get_memory_cell(3));
		}
break;